#########################################################
# Praat script to get labels and durations from TextGrid
# 
# Command line: praat GetDurations filename tiernumber
#
#    where "filename" is a TextGrid file
#    and "tiernumber" is the tier to use.
#
# Output: duration time1 time2 label
#########################################################
#
##########################################
# Get TG base and tiernumber
#     (from command line or interactively)
##########################################
form textgridbase tiernumber
   word textgridbase_(without .TextGrid extension) foo
   integer tiernumber 1
endform
#
######################
# Read in TextGridFile
######################
grid$ = "'textgridbase$'.TextGrid"
Read from file... 'grid$'
outfile$ = "'textgridbase$'.dur'tiernumber'"
printline 'outfile$'
#
###################################
# Interate over TextGrid intervals:
###################################
select TextGrid 'textgridbase$'
textgrid = selected("TextGrid")
n = Get number of intervals... tiernumber
filedelete 'outfile$'
#
for i to n
  label$ = Get label of interval... tiernumber i
  t1 = Get starting point... tiernumber i
  t2 = Get end point... tiernumber i
  dur = t2-t1
  printline 'dur:3' 't1:3' 't2:3' 'label$'
  fileappend 'outfile$' 'dur:3' 't1:3' 't2:3' 'label$' 'newline$'
endfor